Custom Distribution

Setup
 
[Setup]
; Name of the application
AppName=WinSCP3 (provided by Some Company)
; not to allow installation while WinSCP is running
AppMutex=WinSCP
; Installation directory (can be changed by user)
DefaultDirName={pf}\WinSCP3
; Start menu group name
DefaultGroupName=WinSCP3 (provided by Some Company)
; Name of the application including version
AppVerName=WinSCP 3.7.5
 
[Files]
; Install WinSCP itself
Source: "WinSCP3.exe"; DestDir: "{app}"; \
  Flags: ignoreversion
; It is recommended (especially for not experienced users) to install
; drag&drop shell extension
Source: "DragExt.dll"; DestDir: "{app}"; \
  Flags: ignoreversion regserver restartreplace restartreplace uninsrestartdelete
 
[Icons]
; Start menu icon
Name: "{group}\WinSCP"; Filename: "{app}\WinSCP3.exe"
; Desktop icon
Name: "{userdesktop}\WinSCP3"; Filename: "{app}\WinSCP3.exe"
 
[Registry]
#define RegistryKey "Software\Martin Prikryl\WinSCP 2"
; Make Explorer-like interface initial setting
; (recommended especially for not experienced users)
; Remove or use value 0 for Norton Commander interface
Root: HKCU; SubKey: "{#RegistryKey}\Configuration\Interface"; ValueType: dword; \
  ValueName: "Interface"; ValueData: 1
; Enable using of drag&drop shell extension
Root: HKCU; SubKey: "{#RegistryKey}\Configuration\Interface"; ValueType: dword; \
  ValueName: "DDExtEnabled"; ValueData: 1; \
  Flags: uninsdeletevalue
 
[Run]
; Offer starting WinSCP after installation
Filename: "{app}\WinSCP3.exe"; Description: "Launch &WinSCP"; \
  Flags: nowait postinstall skipifsilent
 
[UninstallRun]
; Offer configuration cleanup on uninstallation
Filename: "{app}\WinSCP3.exe"; Parameters: "/UninstallCleanup"; \
  RunOnceId: "UninstallCleanup"
 
; ????
[UninstallDelete]
Type: files; Name: "{app}\WinSCP3.ini"
 

Read documentation.

• Using INI file as configuration storage.
• Setting up autologin.
• Using embedded settings (that cannot be overridden).